LibreOffice 25.2 Help
LibreLogo គឺជាបរិស្ថានកម្មវិធីដែលបានបកប្រែ ងាយស្រួល Logo-like ជាមួយក្រាហ្វិកវ៉ិចទ័រអណ្ដើកសម្រាប់បង្រៀនគណនា (កម្មវិធី និងការវាយអត្ថបទ), DTP និងការរចនាក្រាហ្វិក។ សូមមើល http://www.numbertext.org/logo/librelogo.pdf ។
The LibreLogo toolbar () contains turtle moving, program start, stop, home, clear screen, program editor/syntax highlighting/translating icons and an input bar (command line).
វាសមមូលទៅនឹងពាក្យបញ្ជារូបសញ្ញា “FORWARD 10”, “BACK 10”, “LEFT 15”, “RIGHT 15” ។ ការចុចលើរូបតំណាង ក៏នឹងផ្ដោតរូបរាងអណ្ដើកឲ្យរមូរទំព័រទៅកាន់ទីតាំងរបស់វាផងដែរ។
ចុចនៅលើរូបតំណាង “ចាប់ផ្ដើមកម្មវិធីឡូហ្គោ” ដើម្បីប្រតិបត្តិអត្ថបទ (ឬបានជ្រើសតែ) អត្ថបទនៃឯកសារ Writer ជាកម្មវិធី LibreLogo ។ នៅក្នុងឯកសារទទេ ឧទាហរណ៍កម្មវិធីនឹងត្រូវបានបញ្ចូល និងប្រតិបត្តិ។
ចុចនៅលើ “Stop” ដើម្បីបញ្ឈប់ការប្រតិបត្តិកម្មវិធី។
ចុចនៅលើរូបតំណាង “ដើម” ដើម្បីកំណត់ទីតាំង ហើយកំណត់ turtle ។
ចុចលើរូបតំណាង “សម្អាតអេក្រង់” ដើម្បីយកចេញធាតុគំនូរនៃឯកសារ។
The “magic wand” icon sets 2-page layout for program editing, expands and converts to uppercase the abbreviated, lowercase Logo commands in the Writer document. Change the language of the document () and click on this icon to translate the Logo program to the selected language.
ចុចបញ្ចូលក្នុងបន្ទាត់ពាក្យបញ្ជា ដើម្បីប្រតិបត្តិមាតិការបស់វា។ ដើម្បីបញ្ឈប់កម្មវិធីប្រើរូបតំណាង “Stop” ។
សង្កត់គ្រាប់ចុចបញ្ចូល (Enter) ដើម្បីដំណើរការបន្ទាត់ពាក្យបញ្ជាម្ដងទៀត ឧទាហរណ៍នៅលើលំដាប់ពាក្យបញ្ជាដូចខាងក្រោម៖
FORWARD 200 LEFT 89
To reset the command line triple-click it or press CommandCtrl+A to select the previous commands, and type the new commands.
Turtle shape of LibreLogo is a normal fixed size drawing object. You can position and rotate it on standard way, too, using the mouse and the Rotate icon of the Drawing Object Properties toolbar. Modify Line Thickness, Line Color and Area Color settings of the turtle shape to set PENSIZE, PENCOLOR and FILLCOLOR attributes of LibreLogo.
កម្មវិធី និងគំនូររូបភាពរបស់ LibreLogo ប្រើឯកសារ Writer ដូចគ្នា។ រូបភាព LibreLogo គឺនៅលើទំព័រដំបូងនៃឯកសារ Writer ។ អ្នកអាចបញ្ចូលការចុះបន្ទាត់មុនកម្មវិធី LibreLogo និងកំណត់ការបង្រីកទំព័រដោយប្រើរូបតំណាង “magic wand” នៃរបារឧបករណ៍រូបសញ្ញា, មានការផ្លាស់ប្ដូរទំហំពុម្ពអក្សរផងដែរសម្រាប់ប្លង់ទំព័រ ២ សម្រាប់ការសរសេរកម្មវិធីរបស់ LibreLogo ៖ ទំព័រ (ដំបូង) ខាងឆ្វេងជារូបភាព, ទំព័រ (ទីពីរ) ខាងស្ដាំជាកម្មវិធីកែសម្រួលកម្មវិធីរបស់ LibreLogo ។
LibreLogo គឺជាភាសាកម្មវិធី Logo-like ដែលអាចបកប្រែបានយ៉ាងងាយស្រួល ហើយបានបកប្រែជាភាសាមួយចំនួនដោយសហគមន៍ភាសាដើមរបស់ LibreOffice ។ វាឆបគ្នាខាងក្រោយជាមួយប្រព័ន្ធ Logo ដែលចាស់ជាង ក្នុងករណីដែលកម្មវិធី Logo ធម្មតាត្រូវបានប្រើក្នុងការអប់រំ ឧទាហរណ៍។
TO triangle :size
REPEAT 3 [
FORWARD :size
LEFT 120
]
END
triangle 10 triangle 100 triangle 200
បញ្ជីសមាជិកត្រូវបានបំបែកដោយសញ្ញាក្បៀស៖ POSITION [0, 0]
ប្លុក និងបញ្ជីកម្មវិធីគឺខុសគ្នា
ប្លុកកម្មវិធីត្រូវការដកឃ្លា ឬជួរថ្មីនៅពេលដាក់ក្នុងវង់ក្រចក៖ REPEAT 10 [ FORWARD 10 LEFT 36 ]
បញ្ជីទាមទារបិទវង់ក្រចក៖ POSITION [0, 0], and not POSITION [ 0, 0 ]
មិនបានគាំទ្រការប្រកាសអនុគមន៍ 1-line (TO និង END ត្រូវការបន្ទាត់ថ្មី)។
សញ្ញាចុចពីរ (:) ជាជម្រើសនៅមុខឈ្មោះអថេរ។
TO ទំហំត្រីកោណ
REPEAT 3 [ FORWARD size LEFT 120 ]
END
ចំណារខ្សែអក្សរគាំទ្រអក្ខរាវិរុទ្ធ និងវាក្យសម្ពន្ធ Python ផងដែរ។
PRINT "ពាក្យ ; វាក្យសម្ពន្ធ Logo ដើម
PRINT “អត្ថបទបំពាន” ; អក្ខរាវិរុទ្ធ Writer
PRINT 'អត្ថបទបំពាន' ; វាក្យសម្ពន្ធ Python
បញ្ជី Python និងខ្សែអក្សរដោះស្រាយ
PRINT “text”[2] ; print “x”
PRINT “text”[1:3] ; print “ex”
Python-like FOR loop
ការប្រកាសអថេរ Python-like ៖
x = 15
PRINT x
គ្មានអនុគមន៍សំណួរបន្ថែមទេ៖
PRINT FILLCOLOR
p = POSITION
PRINT p
REPEAT 10 [ POSITION ANY POSITION p ]
ការដាក់រង្វង់ក្រចកឆ្លាស់នៅក្នុងអនុគមន៍ហៅ
TO star size color
FILLCOLOR color
REPEAT 5 [ LEFT 72 FORWARD size RIGHT 144 FORWARD size ]
FILL
END
star 100 “red”
star(100, “green”)
star(100, “blue”)
ពាក្យបញ្ជា និងពណ៌គឺមិនប្រកាន់អក្សរតូចធំ៖
PRINT “Hello, World!”
បង្ហាញ “Hello, World, again!”
ឈ្មោះអថេរគឺប្រកាន់អក្សរតូចធំ៖
a = 5
A = 7
PRINT a
PRINT A
Lines of a LibreLogo program are paragraphs in the Writer document. A program line can contain multiple commands:
PRINT “Hello, World!” PRINT “LibreLogo”
ផ្នែកបន្ទាត់គឺជាសេចក្ដីអធិប្បាយចាប់ពីសញ្ញាចំណុចក្បៀសទៅចុងបន្ទាត់ (កថាខណ្ឌ)៖
; សេចក្ដីអធិប្បាយ
PRINT 5 * 5 ; សេចក្ដីអធិប្បាយ
វាអាចបំបែកបន្ទាត់កម្មវិធីសម្រាប់កថាខណ្ឌច្រើនដោយប្រើសញ្ញា ~ នៅចុងបន្ទាត់៖
PRINT “វាគឺវែងណាស់ ” + ~
“សារព្រមាន”
FORWARD 10 ; បញ្ជូនបន្តទៅមុខ 10pt (1pt = 1/72 inch)
FORWARD 10pt ; មើលខាងលើ
FORWARD 0.5in ; ផ្លាស់ទីទៅមុខ 0.5 inch (1 inch = 2.54 cm)
FORWARD 1" ; មើលខាងលើ
FD 1mm
FD 1cm
BACK 10 ; ផ្លាស់ទីថយក្រោយ 10pt
LEFT 90 ; បង្វិល 90 ដឺក្រេច្រាសទ្រនិចនាឡិកា
LEFT 90° ; មើលខាងលើ
LT 3h ; មើលខាងលើ (ទីតាំងនាឡិកា)
LT any ; បង្វិលទៅទីតាំងចៃដន្យ
RIGHT 90 ; បង្វិល ៩០ ដឺក្រេស្របទ្រនិចនាឡិកា
PENUP ; អណ្ដើកនឹងផ្លាស់ទីដោយគ្មានស្នាម
PENDOWN ; អណ្ដើកនឹងផ្លាស់ទីជាមួយគំនូរ
POSITION [0, 0] ; បង្វិល និងផ្លាស់ទីទៅជ្រុងលើខាងឆ្វេង
POSITION PAGESIZE ; បង្វិល និងផ្លាស់ទីទៅជ្រុងក្រោមខាងស្ដាំ
POSITION [PAGESIZE[0], 0] ; បង្វិល និងផ្លាស់ទីទៅជ្រុងលើខាងស្ដាំ
POSITION ANY ; បង្វិល និងផ្លាស់ទីទៅទីតាំងចៃដន្យ
HEADING 0 ; ត្រឡប់ទៅខាងជើង
HEADING 12h ; មើលខាងលើ
HEADING [0, 0] ; ត្រឡប់ទៅជ្រុងលើខាងឆ្វេង
HEADING ANY ; ត្រឡប់ទៅទិសដៅចៃដន្យ
HIDETURTLE ; លាក់អណ្ដើក (រហូតដល់ពាក្យបញ្ជាបង្ហាញអណ្ដើក)
SHOWTURTLE ; បង្ហាញអណ្ដើក
HOME ; reset initial turtle position
CLEARSCREEN ; លុបវត្ថុគំនូររបស់ឯកសារចេញ
FILL ; close and fill the actual line shape or points
CLOSE ; close the actual line shape or join the actual points
Example: filling a regular triangle:
FORWARD 50 LEFT 120 FORWARD 50 FILL
Example: drawing a regular triangle:
FORWARD 50 LEFT 120 FORWARD 50 CLOSE
PENSIZE 100 ; line thickness is 100 points
PENSIZE ANY ; equivalent of PENSIZE RANDOM 10
PENCOLOR “red” ; កំណត់ពណ៌ប៊ិចក្រហម (ដោយឈ្មោះពណ៌ មើលលំនឹងពណ៌)
PENCOLOR [255, 255, 0] ; កំណត់ពណ៌លឿង (បញ្ជី RGB)
PENCOLOR 0xffff00 ; កំណត់ពណ៌លឿង (កូដគោលដប់ប្រាំមួយ)
PENCOLOR 0 ; កំណត់ពណ៌ខ្មៅ (0x000000)
PENCOLOR ANY ; ពណ៌ចៃដន្យ
PENCOLOR [5] ; កំណត់ពណ៌ក្រហម (ដោយគ្រឿងសម្គាល់ពណ៌ មើលលំនឹងពណ៌)
PENCOLOR “invisible” ; បិទពណ៌ប៊ិចសម្រាប់រូបរាងដោយមើលមិនឃើញគែម
PENCOLOR “~red” ; កំណត់ពណ៌ក្រហមចៃដន្យ
PENTRANSPARENCY 80 ; កំណត់ភាពថ្លានៃពណ៌របស់ប៊ិកជាក់ស្ដែងដល់ 80%
PENCAP “none” ; គ្មានបន្ទាត់បន្ថែមនៅចុង (លំនាំដើម)
PENCAP “round” ; បន្ទាត់មូលនៅចុង
PENCAP “square” ; បន្ទាត់ការ៉េនៅចុង
PENJOINT “rounded” ; ភ្ជាប់បន្ទាត់ជារង្វង់ (លំនាំដើម)
PENJOINT “miter” ; ភ្ជាប់បន្ទាត់ស្រួច
PENJOINT “bevel” ; ភ្ជាប់បន្ទាត់ទេរ
PENJOINT “none” ; ដោយមិនភ្ជាប់បន្ទាត់
PENSTYLE “solid” ; បន្ទាត់ជាប់ (លំនាំដើម)
PENSTYLE “dotted” ; បន្ទាត់ចុចៗ
PENSTYLE “dashed” ; បន្ទាត់ដាច់ៗ
; លំនាំចុចៗដាច់ៗផ្ទាល់ខ្លួនដែលបានបញ្ជាក់ដោយបញ្ជីដែលមានអាគុយម៉ង់ដូចខាងក្រោម៖
; – ចំនួនចុចៗដែលនៅជិត
; – ប្រវែងចំណុច
; – ចំនួនបន្ទាត់ដាច់ៗដែលនៅជិត
; – ប្រវែងបន្ទាត់ដាច់ៗ
; – ចម្ងាយចំណុច/បន្ទាត់ដាច់ៗ
; – ប្រភេទ (ចំណុច)៖
; ០ = ចំណុចជាចតុកោណ (លំនាំដើម)
; ២ = ចំណុចជាការ៉េ (ប្រវែង និងចម្ងាយដែលពាក់ព័ន្ធនឹងទំហំប៊ិច)
PENSTYLE [3, 1mm, 2, 4mm, 2mm, 2] ; ...––...––...––
FILLCOLOR “blue” ; fill with blue color, see also PENCOLOR
FILLCOLOR “invisible” CIRCLE 10 ; unfilled circle
FILLCOLOR [“blue”, “red”] ; gradient between red and blue
FILLCOLOR [[255, 255, 255], [255, 128, 0]] ; between white and orange
FILLCOLOR [“blue”, “red”, 1, 0, 0] ; set axial gradient (with the required rotation and border settings), possible values: 0-5 = linear, axial, radial, elliptical, square and rectangle gradients
FILLCOLOR [“red”, “blue”, 0, 90, 20] ; linear with 20% border, rotated with 90 degrees from the actual heading of the turtle
FILLCOLOR [“red”, “blue”, 0, 90, 20, 0, 0, 200, 50] ; from 200% to 50% intensity
FILLCOLOR [ANY, ANY, 2, 0, 0, 50, 50] ; radial gradient with random colors and 50-50% horizontal and vertical positions of the center
FILLTRANSPARENCY 80 ; កំណត់ភាពថ្លានៃពណ៌បំពេញពិតប្រាកដ 80%
FILLTRANSPARENCY [80] ; កំណត់ជម្រាលភាពថ្លាពី 80% ដល់ 0%
FILLTRANSPARENCY [80, 20] ; កំណត់ជម្រាលភាពថ្លាលីនេអ៊ែរពី 80% ដល់ 20%
FILLTRANSPARENCY [80, 20, 1, 90] ; កំណត់ជម្រាលភាពថ្លាអ័ក្សដែលបានបង្វិល 90 ដឺក្រេពីក្បាលជាក់ស្ដែង turtle
FILLTRANSPARENCY [80, 20, 2, 0, 20, 50, 50] ; កំណត់ជម្រាលភាពថ្លាកាំពីខាងក្រៅ 80% ទៅខាងក្នុង 20% ភាពថ្លាដែលមានស៊ុម 20% និងទីតាំងបញ្ឈរ និងផ្ដេក 50-50% នៃកណ្ដាល
FILLSTYLE 0 ; បំពេញដោយគ្មានឆ្នូត (លំនាំដើម)
FILLSTYLE 1 ; ឆ្នូតខ្មៅមួយ (ផ្ដេក)
FILLSTYLE 2 ; ឆ្នូតខ្មៅមួយ (៤៥ ដឺក្រេ)
FILLSTYLE 3 ; ឆ្នូតខ្មៅមួយ (-៤៥ ដឺក្រេ)
FILLSTYLE 4 ; ឆ្នូតខ្មៅមួយ (បញ្ឈរ)
FILLSTYLE 5 ; ឆ្នូតក្រហមកាត់ (៤៥ ដឺក្រេ)
FILLSTYLE 6 ; ឆ្នូតក្រហមកាត់ (០ ដឺក្រេ)
FILLSTYLE 7 ; ឆ្នូតខៀវកាត់ (៤៥ ដឺក្រេ)
FILLSTYLE 8 ; ឆ្នូតខៀវកាត់ (០ ដឺក្រេ)
FILLSTYLE 9 ; ពណ៌ខៀវកាត់បី
FILLSTYLE 10 ; ឆ្នូតខ្មៅមួយធំ (៤៥ដឺក្រេ)
; ឆ្នូតផ្ទាល់ខ្លួនបញ្ជាក់ដោយបញ្ជីដែលមានអាគុយម៉ង់ដូចខាងក្រោម៖
; – style (1 = តែមួយ, 2 = ទ្វេ, 3 = ឆ្នូតបី)
; – color
; – distance
; – degree
FILLSTYLE [2, “green”, 3pt, 15°] ; ឆ្នូតបៃតងកាត់ (១៥ ដឺក្រេ)
CIRCLE 100 ; គូររាងរង្វង់ (អង្កត់ផ្ចិត = 100pt)
ELLIPSE [50, 100] ; គូររង្វង់ពងក្រពើដែលមានអង្កត់ផ្ចិត ៥០ និង ១០០
ELLIPSE [50, 100, 2h, 12h] ; គូរអង្កត់រាងពងក្រពើ (ពីចំណុចម៉ោង ២ ដល់ម៉ោង ១២)
ELLIPSE [50, 100, 2h, 12h, 2] ; គូរអង្កត់រាងពងក្រពើ
ELLIPSE [50, 100, 2h, 12h, 3] ; គូរអ័ក្សរាងពងក្រពើ
SQUARE 100 ; គូររាងការ៉េ (ទំហំ = 100pt)
RECTANGLE [50, 100] ; draw a rectangle shape (50×100pt)
RECTANGLE [50, 100, 10] ; draw a rectangle with rounded corners
POINT ; គូរចំណុចជាមួយទំហំ និងពណ៌របស់ប៊ិច
CLOSE can join the last points, FILL can fill the shape defined by points. For example, it’s easy to draw a “flat” star starting from its center:
PENUP
REPEAT 5 [
FORWARD 80
POINT
BACK 80
RIGHT 36
FORWARD 50
POINT
BACK 50
RIGHT 120
] FILL
LABEL “text” ; បង្ហាញអត្ថបទនៅក្នុងទីតាំងអណ្ដើក
LABEL 'text' ; មើលខាងលើ
LABEL "text ; មើលខាងលើ (សម្រាប់តែពាក្យទោលប៉ុណ្ណោះ)
CIRCLE 10 TEXT “text” ; កំណត់អត្ថបទរបស់អត្ថបទគំនូរជាក់ស្ដែង
FONTCOLOR “green” ; កំណត់ពណ៌ពុម្ពអក្សរ
FONTFAMILY “Linux Libertine G” ; កំណត់ពុម្ពអក្សរ (អំបូរ)
FONTFAMILY “Linux Libertine G:smcp=1” ; កំណត់លក្ខណៈពុម្ពអក្សរផងដែរ (អក្សរពុម្ពតូច)
FONTFAMILY “Linux Libertine G:smcp=1&onum=1” ; អក្សរពុម្ពតូច + រូបរាងចាស់
FONTSIZE 12 ; កំណត់ 12pt
FONTWEIGHT “bold” ; កំណត់ពុម្ពអក្សរដិត
FONTWEIGHT “normal” ; កំណត់លក្ខណៈធម្មតា
FONTSTYLE “italic” ; កំណត់ទ្រេត
FONTSTYLE “normal” ; កំណត់ធម្មតា
PICTURE គឺសម្រាប់
ដាក់រូបរាងជាក្រុម;
ចាប់ផ្ដើមរូបរាងបន្ទាត់ថ្មី;
ការរក្សាទុករូបភាព SVG និង SVG/SMIL មានចលនា
រក្សាលំនឹងទីតាំង និងរាងបន្ទាត់នៅស៊ុមខាងឆ្វេង។
; PICTURE [ LibreLogo_commands ]
PICTURE [ FORWARD 100 CIRCLE 100 ] ; មែកធាងដូចរូបរាងដែលបានដាក់ក្រុម
See also “Group” in LibreOffice Writer Help.
TO tree location
PENUP POSITION location HEADING 0 PENDOWN
PICTURE [ FORWARD 100 CIRCLE 100 ] ; tree-like grouped shape
END
PICTURE [ tree [230, 400] tree [300, 400] ] ; grouped shapes in a grouped shape
PICTURE ; ចាប់ផ្ដើមរាងបន្ទាត់ថ្មី
FORWARD 10 PICTURE FORWARD 10 ; រាងបន្ទាត់ពីរជាន់
PICTURE “example.svg” [ CIRCLE 5 ] ; រក្សាទុករូបភាពជាឯកសាររូបភាព SVG នៅក្នុងថតអ្នកប្រើ
PICTURE “Desktop/example.svg” [ FORWARD 100 CIRCLE 5 ] ; ដូចខាងលើជាមួយផ្លូវពាក់ព័ន្ធ
PICTURE “/home/user/example.svg” [ CIRCLE 5 ] ; ផ្លូវដាច់ខាតសម្រាប់ Unix/Linux
PICTURE “C:\example.svg” [ CIRCLE 5 ] ; ផ្លូវដាច់ខាតសម្រាប់ Windows
PICTURE “animation.svg” [ CIRCLE 5 SLEEP 1000 CIRCLE 99 ] ; រក្សាទុក SVG/SMIL ចលនា (មើលផងដែរ SLEEP)
PICTURE “animation2.svg” [ CIRCLE 5 SLEEP 1000 CIRCLE 99 SLEEP 2000 ] ; ដូចខាងលើដែរ ប៉ុន្តែប្រើ SLEEP បន្ទាប់ពីវត្ថុចុងក្រោយនឹងមានលទ្ធផលរង្វិលជុំ៖ បន្ទាប់ពី ២ វិនាទី ចលនា SVG ចាប់ផ្ដើមឡើងវិញនៅក្នុងកម្មវិធីអ៊ីនធឺណិត SMIL-conformant
Use PICTURE to keep the consistency of positions and line shapes at the left border of Writer:
PICTURE [ CIRCLE 20 POSITION [-100, 100] CIRCLE 20 ]
; REPEAT number [ commands ]
REPEAT 10 [ FORWARD 10 LEFT 45 CIRCLE 10 ] ; ធ្វើឡើងវិញ ១០ ដង
; លេខគឺជាជម្រើស
REPEAT [ POSITION ANY ] ; រង្វិលជុំរហូត
អថេររង្វិលជុំ (មានផងដែរនៅក្នុង FOR និង WHILE loops)។
REPEAT 100 [ FORWARD REPCOUNT LEFT 90 ]
រង្វិលជុំសម្រាប់ធាតុបញ្ជី៖
FOR i IN [1, 5, 7, 9, 11] [
FORWARD i
LEFT 90
]
រង្វិលជុំសម្រាប់តួអក្សរនៃលំដាប់តួអក្សរ៖
FOR i IN “text” [
LABEL i
FORWARD 10
]
WHILE TRUE [ POSITION ANY ] ; endless loop
WHILE REPCOUNT <= 10 [ FORWARD 50 LEFT 36 ] ; as REPEAT 10 [ ... ]
បញ្ឈប់រង្វិលជុំ។
REPEAT [ ; endless loop
POSITION ANY
IF REPCOUNT = 100 [ BREAK ] ; equivalent of the REPEAT 100 [ ... ]
]
ទៅកាន់ការធ្វើឡើងវិញបន្ទាប់របស់រង្វិលជុំ។
REPEAT 100 [
POSITION ANY
IF REPCOUNT % 2 = 0 [ CONTINUE ]
CIRCLE 10 ; គូររង្វង់នៅរាល់ទីតាំងទី២
]
; IF condition [ true block ]
; IF condition [ true block ] [ false block ]
IF a < 10 [ PRINT “Small” ]
IF a < 10 [ PRINT “Small” ] [ PRINT “Big” ]
សញ្ញាប្រមាណវិធីតក្កវិជ្ជា។
IF a < 10 AND NOT a = 5 [ PRINT “0, 1, 2, 3, 4, 6, 7, 8 or 9” ]
IF a < 10 AND a != 5 [ PRINT “0, 1, 2, 3, 4, 6, 7, 8 or 9” ] ; ដូចខាងលើ
ពាក្យថ្មី (ឬបែបបទ)។
TO triangle
REPEAT 2 [ FORWARD 100 RIGHT 120 ] FILL
END
REPEAT 10 [ triangle PENUP POSITION ANY PENDOWN ]
ត្រឡប់តម្លៃនៃអនុគមន៍។
TO randomletter
OUTPUT RANDOM “qwertzuiopasdfghjklyxcvbnm”
END
PRINT randomletter + randomletter + randomletter ; print 3-letter random character sequence
ត្រឡប់ពីបែបបទ។
TO example number
IF number < 0 [ STOP ]
PRINT SQRT number ; បង្ហាញឫសការ៉េ
]
ឧទាហរណ៍ 100
ឧទាហរណ៍ -1 ; មានកំហុស និងគ្មានលទ្ធផល
ឧទាហរណ៍ 25
តម្លៃពណ៌លំនាំដើម។ល។
PENCOLOR ANY ; ពណ៌ប៊ិចចៃដន្យ
តម្លៃតក្កវិជ្ជា។
WHILE TRUE [ POSITION ANY ] ; រង្វិលជុំមិនចេះចប់
PRINT TRUE ; បង្ហាញពិត
តម្លៃតក្កវិជ្ជា។
WHILE NOT FALSE [ POSITION ANY ] ; រង្វិលជុំមិនចេះចប់
PRINT FALSE ; បង្ហាញមិនពិត
PRINT PAGESIZE ; បង្ហាញបញ្ជីទំហំទំព័រគិតជាចំណុច, ឧ. [595.30, 841.89]
PRINT PI ; បង្ហាញ 3.14159265359
PRINT “text” ; បង្ហាញ “text” នៅក្នុងប្រអប់
PRINT 5 + 10 ; បង្ហាញ 15
PRINT INPUT “Input value?” ; សួរ និងបង្ហាញដោយប្រអប់សំណួរ
PRINT FLOAT (INPUT “First number?”) + FLOAT (INPUT “Second number?”) ; ការគណនាធម្មតា
SLEEP 1000 ; រង់ចាំ ១០០ ម.វិ. (១ វិនាទី)
កំណត់អថេរសាកលដែលបានប្រើដោយបែបបទ។
GLOBAL about
about = “LibreLogo”
TO example
PRINT about
GLOBAL about ; ពេលយើងចង់បន្ថែមតម្លៃថ្មី
about = “new value for the global variable”
END
example
PRINT about
PRINT RANDOM 100 ; ចំនួនទសភាគចៃដន្យ (0 <= x < 100)
PRINT RANDOM “text” ; អក្សរចៃដន្យរបស់ “text”
PRINT RANDOM [1, 2] ; ធាតុបញ្ជីចៃដន្យ (១ ឬ ២)
PRINT INT 3.8 ; បង្ហាញលេខ 3 (ផ្នែកគត់របស់ 3.8)
PRINT INT RANDOM 100 ; លេខចំនួនគត់ចៃដន្យ (0 <= x < 100)
PRINT INT “7” ; បម្លែងប៉ារ៉ាម៉ែត្រតួអក្សរទៅជាចំនួនគត់
; បម្លែងប៉ារ៉ាម៉ែត្រតួអក្សរទៅជាចំនួនទសភាគ
PRINT 2 * FLOAT “5.5” ; បង្ហាញ 11.0
; បម្លែងប៉ារ៉ាម៉ែត្រលេខទៅជាតួអក្សរ
PRINT “Result: ” + STR 5 ; បង្ហាញ “Result: 5”
PRINT 10 * STR 5 ; បង្ហាញ 5555555555
PRINT SQRT 100 ; បង្ហាញ 10, ឫសការ៉េនៃ 100
PRINT SIN 90 * PI/180 ; បង្ហាញ 1.0 (ស៊ីនុសរបស់មុំ 90°)
PRINT COS 0 * PI/180 ; បង្ហាញ 1.0 (កូស៊ីនុសរបស់មុំ 0°)
PRINT LOG10 100 ; print 2.0 (ឡូការីតទូទៅ 100)
PRINT ROUND 3.8 ; បង្ហាញ 4 (ការបង្គត់ 3.8)
PRINT ROUND RANDOM 100 ; ចំនួនគត់ចៃដន្យ (0 <= x <= 100)
PRINT ABS -10 ; បង្ហាញលេខ 10, តម្លៃដាច់ខាតរបស់ -10
PRINT COUNT “text” ; បង្ហាញលេខ 4, ចំនួនតួអក្សររបស់ “text”
PRINT COUNT [1, 2, 3] ; បង្ហាញលេខ 3, ទំហំបញ្ជី
; បម្លែងបញ្ជីទៅជាសំណុំ Python
PRINT SET [4, 5, 6, 6] ; បង្ហាញ {4, 5, 6}
PRINT SET [4, 5, 6, 6] | SET [4, 1, 9] ; បង្ហាញ {1, 4, 5, 6, 9}, ប្រជុំ
PRINT SET [4, 5, 6, 6] & SET [4, 1, 9] ; បង្ហាញ {4}, ប្រសព្វ
PRINT SET ([4, 5, 6, 6]) - SET [4, 1, 9] ; បង្ហាញ {5, 6}, ផលដក
PRINT SET [4, 5, 6, 6] ^ SET [4, 1, 9] ; បង្ហាញ {1, 5, 6, 9}, ផលដកស៊ីមេទ្រី
; Python-like list generation
PRINT LIST RANGE 10 ; print [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
PRINT LIST RANGE 3 10 ; print [3, 4, 5, 6, 7, 8, 9]
PRINT LIST RANGE 3 10 3 ; print [3, 6, 9]
FOR i IN RANGE 10 50 10 [ ; loop for [10, 20, 30, 40]
FORWARD i
LEFT 90
]
; លុបធាតុជាន់គ្នានៃបញ្ជីដោយប្រើសំណុំ និងបញ្ជីបម្លែង
PRINT LIST (SET [1, 3, 5, 5, 2, 1]) ; បង្ហាញ [1, 3, 5, 2]
ការបម្លែងទៅ Python tuple (បញ្ជីមិនអាចកែប្រែបាន)
PRINT TUPLE [4, 5]
វាផ្ដល់ត្រឡប់នូវបញ្ជីតម្រៀប។
PRINT SORTED [5, 1, 3, 4] ; បង្ហាញ [1, 3, 4, 5]
ជំនួសលំដាប់អក្សរដោយប្រើលំនាំ regex (កន្សោមធម្មតា) ។
PRINT SUB (“t”, “T”, “text”) ; បង្ហាញ “Text”, ជំនួស “t” ដោយ “T”
PRINT SUB (“(.)”, “\\1\\1”, “text”) ; បង្ហាញ “tteexxtt”, បង្កើនទ្វេអក្សរនីមួយៗ
ស្វែងរកលំនាំលំដាប់តួអក្សរដោយប្រើលំនាំ regex ។
IF SEARCH (“\w”, "word") [ PRINT “Letter in the word.” ]
រកលំដាប់តួអក្សរទាំងអស់នៅក្នុងខ្សែអក្សរបញ្ចូលដែលផ្គូផ្គងជាមួយលំនាំ regex ដែលបានផ្ដល់។
PRINT FINDALL(“\w+”, “Dogs, cats.”) ; បង្ហាញ [“Dogs”, “cats”], បញ្ជីពាក្យ។
PRINT MIN [1, 2, 3] ; បង្ហាញលេខ 1, ធាតុដែលទាបបំផុតនៅក្នុងបញ្ជី
PRINT MAX [1, 2, 3] ; បង្ហាញលេខ 3, ធាតុដែលធំបំផុតនៅក្នុងបញ្ជី
PENCOLOR “SILVER” ; កំណត់តាមឈ្មោះ
PENCOLOR [1] ; កំណត់តាមគ្រឿងសម្គាល់
PENCOLOR “~SILVER” ; ពណ៌ប្រាក់ចៃដន្យ
| គ្រឿងសម្គាល់ | ឈ្មោះ | 
|---|---|
| ០ | BLACK | 
| ១ | SILVER | 
| ២ | GRAY/GREY | 
| ៣ | WHITE | 
| ៤ | MAROON | 
| ៥ | RED | 
| ៦ | PURPLE | 
| ៧ | FUCHSIA/MAGENTA | 
| ៨ | GREEN | 
| ៩ | LIME | 
| 10 | OLIVE | 
| 11 | YELLOW | 
| 12 | NAVY | 
| 13 | BLUE | 
| 14 | TEAL | 
| 15 | AQUA | 
| 16 | PINK | 
| ១៧ | TOMATO | 
| 18 | ORANGE | 
| ១៩ | GOLD | 
| 20 | VIOLET | 
| ២១ | SKYBLUE | 
| 22 | CHOCOLATE | 
| ២៣ | BROWN | 
| 24 | INVISIBLE |